git.r.bdr.sh - rbdr/dotfiles/blob - vim/ftplugin/haml.vim

   1 " Vim filetype plugin
   2 " Language:     Haml
   3 " Maintainer:   Tim Pope <vimNOSPAM@tpope.org>
   4 " Last Change:  2010 May 21
   5
   6 " Only do this when not done yet for this buffer
   7 if exists("b:did_ftplugin")
   8   finish
   9 endif
  10
  11 let s:save_cpo = &cpo
  12 set cpo-=C
  13
  14 " Define some defaults in case the included ftplugins don't set them.
  15 let s:undo_ftplugin = ""
  16 let s:browsefilter = "All Files (*.*)\t*.*\n"
  17 let s:match_words = ""
  18
  19 runtime! ftplugin/html.vim ftplugin/html_*.vim ftplugin/html/*.vim
  20 unlet! b:did_ftplugin
  21
  22 " Override our defaults if these were set by an included ftplugin.
  23 if exists("b:undo_ftplugin")
  24   let s:undo_ftplugin = b:undo_ftplugin
  25   unlet b:undo_ftplugin
  26 endif
  27 if exists("b:browsefilter")
  28   let s:browsefilter = b:browsefilter
  29   unlet b:browsefilter
  30 endif
  31 if exists("b:match_words")
  32   let s:match_words = b:match_words
  33   unlet b:match_words
  34 endif
  35
  36 runtime! ftplugin/ruby.vim ftplugin/ruby_*.vim ftplugin/ruby/*.vim
  37 let b:did_ftplugin = 1
  38
  39 " Combine the new set of values with those previously included.
  40 if exists("b:undo_ftplugin")
  41   let s:undo_ftplugin = b:undo_ftplugin . " | " . s:undo_ftplugin
  42 endif
  43 if exists ("b:browsefilter")
  44   let s:browsefilter = substitute(b:browsefilter,'\cAll Files (\*\.\*)\t\*\.\*\n','','') . s:browsefilter
  45 endif
  46 if exists("b:match_words")
  47   let s:match_words = b:match_words . ',' . s:match_words
  48 endif
  49
  50 " Change the browse dialog on Win32 to show mainly Haml-related files
  51 if has("gui_win32")
  52   let b:browsefilter="Haml Files (*.haml)\t*.haml\nSass Files (*.sass)\t*.sass\n" . s:browsefilter
  53 endif
  54
  55 " Load the combined list of match_words for matchit.vim
  56 if exists("loaded_matchit")
  57   let b:match_words = s:match_words
  58 endif
  59
  60 setlocal comments= commentstring=-#\ %s
  61
  62 let b:undo_ftplugin = "setl cms< com< "
  63       \ " | unlet! b:browsefilter b:match_words | " . s:undo_ftplugin
  64
  65 let &cpo = s:save_cpo
  66
  67 " vim:set sw=2: