git.r.bdr.sh - rbdr/dotfiles/blob - vim/syntax_checkers/xhtml.vim

   1 "============================================================================
   2 "File:        xhtml.vim
   3 "Description: Syntax checking plugin for syntastic.vim
   4 "Maintainer:  Martin Grenfell <martin.grenfell at gmail dot com>
   5 "License:     This program is free software. It comes without any warranty,
   6 "             to the extent permitted by applicable law. You can redistribute
   7 "             it and/or modify it under the terms of the Do What The Fuck You
   8 "             Want To Public License, Version 2, as published by Sam Hocevar.
   9 "             See http://sam.zoy.org/wtfpl/COPYING for more details.
  10 "
  11 "============================================================================
  12 if exists("loaded_xhtml_syntax_checker")
  13     finish
  14 endif
  15 let loaded_xhtml_syntax_checker = 1
  16
  17 "bail if the user doesnt have tidy or grep installed
  18 if !executable("tidy")
  19     finish
  20 endif
  21
  22 " TODO: join this with html.vim DRY's sake?
  23 function! s:TidyEncOptByFenc()
  24     let tidy_opts = {
  25                 \'utf-8'       : '-utf8',
  26                 \'ascii'       : '-ascii',
  27                 \'latin1'      : '-latin1',
  28                 \'iso-2022-jp' : '-iso-2022',
  29                 \'cp1252'      : '-win1252',
  30                 \'macroman'    : '-mac',
  31                 \'utf-16le'    : '-utf16le',
  32                 \'utf-16'      : '-utf16',
  33                 \'big5'        : '-big5',
  34                 \'sjis'        : '-shiftjis',
  35                 \'cp850'       : '-ibm858',
  36                 \}
  37     return get(tidy_opts, &fileencoding, '-utf8')
  38 endfunction
  39
  40 function! SyntaxCheckers_xhtml_GetLocList()
  41
  42     let encopt = s:TidyEncOptByFenc()
  43     let makeprg="tidy ".encopt." -xml -e ".shellescape(expand('%'))
  44     let errorformat='%Wline %l column %c - Warning: %m,%Eline %l column %c - Error: %m,%-G%.%#,%-G%.%#'
  45     return SyntasticMake({ 'makeprg': makeprg, 'errorformat': errorformat, 'defaults': {'bufnr': bufnr("")} })
  46 endfunction