Add graphql vim plugin

[rbdr/dotfiles] / zsh / modules / prompt.zsh

autoload -Uz promptinit && promptinit

if [[ "$TERM" == (dumb|linux|*bsd*) ]] || (( $#prompt_argv < 1 )); then
  prompt 'off'
fi

#
# Precmd
#

function prompt_precmd {
  git-info
}

#
# Functions
#

function env_info_provider() { echo "%{%F{green}%}n/a"; }
function env_info {
  echo "[%{%F{cyan}%}ENV%{%F{black}%} $(env_info_provider)%{%F{black}%}]"
}

function python_info {
  pythoninfo=`asdf current python | sed 's/  */ /g' | cut -d ' ' -f 2`
  if [[ -z "$VIRTUAL_ENV" ]]; then
    venv="default"
  else
    venv="${VIRTUAL_ENV##*/}"
  fi
  echo "%{%F{green}%}py%{%F{black}%} ${pythoninfo}@${venv}"
}

function ruby_info {
  rubyinfo=`asdf current ruby | sed 's/  */ /g' | cut -d ' ' -f 2`
  echo "%{%F{red}%}rb%{%F{black}%} ${rubyinfo}"
}

function node_info {
  nodeinfo=`asdf current nodejs | sed 's/  */ /g' | cut -d ' ' -f 2`
  echo "%{%F{yellow}%}js%{%F{black}%} ${nodeinfo}"
}

function box_name {
    [ -f ~/.box-name ] && cat ~/.box-name || hostname -s
}

#
# ZLE widgets
#

function zle-line-init zle-keymap-select {

    # Couldn't figure out how to get tmux and iTerm to agree on how to render
    # these characters... so there you go.

    local normal_symbol="N"
    local insert_symbol="I"
    local error_symbol="X"

    # Show vi status / return status on the right side

    local return_status="%{%F{red}%}%(?.. $error_symbol)%{$reset_color%}"
    if [ $KEYMAP = 'vicmd' ]; then
      local edit_status="%{%F{cyan}%}$normal_symbol"
    else
      local edit_status="%{%F{green}%}$insert_symbol"
    fi

    RPROMPT="${edit_status}${return_status}%{$reset_color%}"
    zle reset-prompt
}
zle -N zle-line-init
zle -N zle-keymap-select

#
# Setup Prompt
#

function prompt_setup {
  setopt LOCAL_OPTIONS
  unsetopt XTRACE KSH_ARRAYS
  prompt_opts=(cr percent subst)

  # Load required functions.
  autoload -Uz add-zsh-hook

  # Add hook for calling git-info before each command.
  add-zsh-hook precmd prompt_precmd

  # Set git-info parameters.
  zstyle ':git:info' verbose 'no'
  zstyle ':git:info:branch' format '@%F{cyan}%b%f'
  zstyle ':git:info:clean' format ''
  zstyle ':git:info:added' format '%{%F{green}%}!'
  zstyle ':git:info:modified' format '%{%F{green}%}?'
  zstyle ':git:info:untracked' format '%{%F{magenta}%}?'
  zstyle ':git:info:keys' format \
    'prompt' '%b%a%m%u'

  # Define prompts.
  PROMPT='
%{%F{black}%}$(env_info) $(node_info) $(ruby_info) $(python_info)
%{%F{magenta}%}%n%{%f%}@%{%F{yellow}%}$(box_name)%{%f%} %{%B%F{green}%}${PWD/#$HOME/~}%{%f%b%}${git_info[prompt]} %{%f%}
%(?,,%{${%B%F{white}%}[%?]%{%f%b%} )$ '
}

prompt_setup "$@"
setopt PROMPT_SUBST
setopt PROMPT_PERCENT
setopt TRANSIENT_RPROMPT