subdir('icons')

################################################################################
# Desktop File
################################################################################
desktop_file = i18n.merge_file(
  type: 'desktop',
  input: configure_file(
    input: '@0@.desktop.in.in'.format(base_id),
    output: '@BASENAME@',
    configuration: {
      'app-id': application_id,
      'gettext-domain': gettext_domain
    }
  ),
  output: '@0@.desktop'.format(application_id),
  po_dir: podir,
  install: true,
  install_dir: datadir / 'applications'
)

if desktop_file_validate.found()
  test(
    'validate-desktop',
    desktop_file_validate,
    args: [
      desktop_file.full_path()
    ],
    depends: desktop_file,
  )
endif

################################################################################
# Appdata / Metainfo File
################################################################################
appdata_file = i18n.merge_file(
  input: configure_file(
    input: '@0@.metainfo.xml.in.in'.format(base_id),
    output: '@BASENAME@',
    configuration: {
      'app-id': application_id,
      'gettext-domain': gettext_domain
    }
  ),
  output: '@0@.metainfo.xml'.format(application_id),
  po_dir: podir,
  install: true,
  install_dir: datadir / 'metainfo'
)

if appstream_util.found()
  test(
    'validate-appdata', appstream_util,
    args: [
      'validate', '--nonet', appdata_file.full_path()
    ],
    depends: appdata_file,
  )
endif

################################################################################
# DBUS Service File
################################################################################
configure_file(
  input: '@0@.service.in'.format(base_id),
  output: '@BASENAME@',
  configuration: {
    'app-id': application_id,
    'binary': meson.project_name(),
    'bindir': bindir
    },
  install: true,
  install_dir: datadir / 'dbus-1' / 'services'
)

install_data(
  'wmap.lang',
  install_dir: datadir / 'gtksourceview-5' / 'language-specs'
)