# Maintainer: Ruben Beltran del Rio <wmap@r.bdr.sh>
pkgname=map
pkgver=1.0.0
pkgrel=1
pkgdesc="Wardley Map editor for Linux"
arch=('x86_64' 'aarch64')
url="https://map.tranquil.systems/map-for-linux"
license=('AGPL-3.0-or-later')
depends=('gtk4' 'gtksourceview5' 'cairo')
makedepends=('cargo' 'gettext')
source=()
sha256sums=()

prepare() {
    cd "$startdir/src"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$startdir/src"
    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target

    # Compile translations
    for po_file in po/*.po; do
        locale=$(basename "$po_file" .po)
        mkdir -p "po/$locale/LC_MESSAGES"
        msgfmt "$po_file" -o "po/$locale/LC_MESSAGES/systems.tranquil.Map.mo"
    done

    cargo build --frozen --release
}

package() {
    cd "$startdir/src"

    install -Dm0755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
    install -Dm0644 resources/logo.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/systems.tranquil.Map.svg"
    install -Dm0644 resources/systems.tranquil.Map.desktop "$pkgdir/usr/share/applications/systems.tranquil.Map.desktop"
    install -Dm0644 resources/systems.tranquil.Map.metainfo.xml "$pkgdir/usr/share/metainfo/systems.tranquil.Map.metainfo.xml"
    install -Dm0644 resources/systems.tranquil.Map.service "$pkgdir/usr/share/dbus-1/services/systems.tranquil.Map.service"
    install -Dm0644 resources/wmap.lang "$pkgdir/usr/share/gtksourceview-5/language-specs/wmap.lang"

    for po_file in po/*.po; do
        locale=$(basename "$po_file" .po)
        install -Dm0644 "po/$locale/LC_MESSAGES/systems.tranquil.Map.mo" "$pkgdir/usr/share/locale/$locale/LC_MESSAGES/systems.tranquil.Map.mo"
    done
}